Skype And MediaMonkey!

[Peke]

I'm thinking to make Plugin for MM so that users of Skype could have some Custom MSG when away.

Anyone Willing to Betatest when it is finished and ready for Testing?

Test Script Can be found here:
http://www.mediamonkey.com/forum/viewto ... 9705#59705

[sasapuksic]

I am interested in testing Peke! Thanx!

[powerpill-pacman]

me too!

[Linus]

A good Idea !!!

Pleace inform me:

[Peke]

OK All of you THX for support.
Will keep you posted as it looks that it is worth to write

Any Features you would like to see?

[Lowlander]

Hey guys, have you checked out:

SkyAmp
AMIP

[Teknojnky]

Any Features you would like to see?

Support for all major IM programs!



(yes I realize there are a few solutions already, but it would be nice to have one that directly supports and is intended for MM)

[powerpill-pacman]

I'd like a link to the artist and track that is played to last.fm and/or discogs.

[Peke]

As this is my own project and it is intended for Skype only.

What all of think that could be made beside anouncing what is currently played?

Regarding other IM software Miranda (My prefered) has Full MM support and for others there is support as talked in forum.

[Peke]

Before plugin is done here is Small Script that writes Now Playing track in Skype Mood/User Note textBox.

Enjoy!

Code: Select all

'==========================================================================
' NAME: SkypePlayMood v1.2 (SkypeMoodText.vbs)
'
' AUTHOR : Peke
' DATE   : 10.10.2006
' INSTALL: Download and install Skype4COM Release (https://developer.skype.com/Download)
'          Save This Script in MM\Scripts\Auto folder and restart MM
' NOTE   : Use latest Skype and allow MM to access Skype
'==========================================================================
Dim MoodPrefix, AppOriginal, MediaMonkeyMoodFirst

'Edit MoodPrefix if you want to have Custom Prefix of now Playing Track
MoodPrefix = "MediaMonkey is playing for Me: "

' Append Original Mood text to existing to MediaMonkey Mood Text (Default TRUE)
AppOriginal = True

' Used only if Appending To original Mood Text is TRUE. Change this if you wish that
' MediaMonkey Mood Text is added to Original Mood Text(Default True)
MediaMonkeyMoodFirst = True

'// Attach To MMObject For Debbuging Only
'Dim SDB
'Set SDB = CreateObject("SongsDB.SDBApplication")

Sub OnStartup
  '// Start the Skype client if not Running
  Dim ini, list, list2
  Set ini = SDB.IniFile

  '//Save Skype Mood text to revert on MM Exit
  Set list = GetObject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If list2.count > 0 Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
    If InStr(oSkype.CurrentUserProfile.MoodText,MoodPrefix) = 0 Then
      ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText
    End If
  End If
  Call Script.RegisterEvent(SDB, "OnPlay", "SetSkypeMood")
  Call Script.RegisterEvent(SDB, "OnShutdown", "RevertSkypeMood")
End Sub

Sub SetSkypeMood
  Dim ini, list, list2
  Set ini = SDB.IniFile
  Set list = getobject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If (list2.count > 0) Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
    '//Set Skype Mood text to show now playing
    If Not ((InStr(oSkype.CurrentUserProfile.MoodText,MoodPrefix) > 0) Or (ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText)) Then
      ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText
    End If
    If AppOriginal Then
      If MediaMonkeyMoodFirst Then
        oSkype.CurrentUserProfile.MoodText = MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")" &Chr(13) &Chr(10) &ini.StringValue("SkypeMood","OldMsg")
      Else
        oSkype.CurrentUserProfile.MoodText = ini.StringValue("SkypeMood","OldMsg") &Chr(13) &Chr(10) &MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")"
      End If
    Else
      oSkype.CurrentUserProfile.MoodText = MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")"
    End If
  End If
End Sub

Sub RevertSkypeMood
  '// Start the Skype client if not Running
  Dim ini, list, list2
  Set ini = SDB.IniFile

  Set list = getobject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If list2.count > 0 Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
    '//revert saved Skype Mood
    oSkype.CurrentUserProfile.MoodText = ini.StringValue("SkypeMood","OldMsg")
    '// Clear Saved mood
  End If
End Sub

Feel free to drop me note, how you liked it.

[Linus]

Hi,
where i have to install (Folder) the skype4com.dll File ??

Thank you for answer, Linus

[sasapuksic]

Use this instaler .... DOWNLOAD

THANX Peke!!

[Peke]

You can use any of self install releases like SasaPuksic noted and in case of beta release just extract anywhere and start register.bat which will register DLL with Windows.

Maybe a admin account will be needed but not 100% sure.

@Sasa Puksic
Good music choise. I was watching what you play and I like most of them.

[Peke]

Version 1.1 That Revert Old Mood Text On MM exit can be found here:
http://www.mediamonkey.com/forum/viewto ... 9705#59705

[Peke]

This is Version 1.2:
* Fixed Forced Skype Start It is Not Forced Anymore
* Fixed No more need to have Installed Skype
+ Add check Of changed Original Mood text within Skype While MM is Playing
+ Added option to Append Original Mood text to MM Mood Text
Can Be found Here:
http://www.mediamonkey.com/forum/viewto ... 9705#59705

TO-DO: Some sort of GUI settings

Enjoy!