Skype And MediaMonkey!

[Danzig]

i will download and test this tonight!

just found out about it... hows the progress coming along?

[powerpill-pacman]

Works like a charm. No problems 'till now.

[Peke]

@Danzig
SasaPuskic and Psyxonova Could tell you the results, last time i tested it manualy on Psyxonova he whistles in my ear from the other end (for details ask him) so I'm guessing it is going on.

@powerpill-pacman
Glad to Hear that.

[psyXonova]

@Danzig
SasaPuskic and Psyxonova Could tell you the results, last time i tested it manualy on Psyxonova he whistles in my ear from the other end (for details ask him) so I'm guessing it is going on.

Ok, you got me.... but it was a really nice song... couldnt help it...

[Guest]

The script is Great

but:
if initially (before starting MM) there is no skype mood text (it is blank)
then on MM exit the script crashes with the error #-2147467261- Line: 80, Column: 4


And i wanted to ask: How do i replace track length with Album name
To be clear - i want album name to be displayed in the brackets insetad of track length.

Thanks

[Guest]

Oh, and one more request:

Any chance to do so that the MediaMonkeyMood text dissappears from skype when MediaMonkey is paused or stopped.
At the time being the script stops showing the song in skype only when MM is closed. But it would also make sense to stop showing the song in skype when MM is paused or stopped.
Sometimes i repeat the same song over and over again and ths script shows that song in skype, which is ok. But sometimes, i pause or stop MM in the middle of some crappy song. And the name of the song stays in skype forever (forever being till i decide tu listen to music again and play another song) and my friends wonder why i have on repeat a such crappy song

[Cran]

Hi,

I tried the script with MediaMonkey 3.0.2-RC3, Skype 3.6.0 and
Skype contact 1.0.0.22.

The script is great !

Just two remarks :
1. when you change the leading text for the mood ("MediaMonkey is playing for Me: " ), you have to blank the entry OldMsg in MediaMonkey.ini

2. When you exit MediaMonkey with no track in the playlist, you may
have errors (in Sub RevertSkypeMood)

3. When quitting MediaMonkey or stopping the track, the mood is not
updated. When the music is stopped os stopped, the mood should be reverted to the original mood set

I fixed that 2 and 3.

Here's the script :

Code: Select all

Edited By Peke: Updated Code Below. Thank you Cran

Enjoy !

[Peke]

THX, I thought that people abandoned this script I added small changes for you

Code: Select all

''==========================================================================
' NAME: SkypePlayMood v1.3 (SkypeMoodText.vbs)
'
' AUTHOR : Peke
' ORIGINAL DATE : 10.10.2006
'
' ÇO-AUTHOR : Cran
' UPDATED : 30.01.2008
' INSTALL: Download and install Skype4COM Release (https://developer.skype.com/Download)
'          Save This Script in MM\Scripts\Auto folder and restart MM
' NOTE   : Use latest Skype and allow MM to access Skype
'
' UPDATES:
' v1.3:
'-------
' - revert to original mood when pausing or stopping playback
' - fix script error when closing MediaMonkey with no track.
'==========================================================================
Dim MoodPrefix, AppOriginal, MediaMonkeyMoodFirst

'Edit MoodPrefix if you want to have Custom Prefix of now Playing Track
MoodPrefix = "L'humeur du moment : "

' Append Original Mood text to MediaMonkey Mood Text (Default TRUE)
AppOriginal = True

' Used only if Appending To original Mood Text is TRUE. Change this if you wish that
' MediaMonkey Mood Text is added to Original Mood Text(Default True)
MediaMonkeyMoodFirst = True

'// Attach To MMObject For Debbuging Only
'Dim SDB
'Set SDB = CreateObject("SongsDB.SDBApplication")

' Added by Cran
Dim OldMsg

Sub OnStartup
  '// Start the Skype client if not Running
  Dim ini, list, list2
  Set ini = SDB.IniFile

  '//Save Skype Mood text to revert on MM Exit
  Set list = GetObject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If list2.count > 0 Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
    If InStr(oSkype.CurrentUserProfile.MoodText,MoodPrefix) = 0 Then
      ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText
    End If
  End If
  Call Script.RegisterEvent(SDB, "OnPlay", "SetSkypeMood")
  Call Script.RegisterEvent(SDB, "OnShutdown", "RevertSkypeMood")
  ' Added by Cran : revert to original skype mood
  Call Script.RegisterEvent(SDB, "OnStop", "RevertSkypeMood")
  Call Script.RegisterEvent(SDB, "OnPause", "RevertSkypeMood")
End Sub

Sub SetSkypeMood
  Dim ini, list, list2
  Set ini = SDB.IniFile
  Set list = getobject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If (list2.count > 0) Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
    '//Set Skype Mood text to show now playing
    If Not ((InStr(oSkype.CurrentUserProfile.MoodText,MoodPrefix) > 0) Or (ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText)) Then
      ini.StringValue("SkypeMood","OldMsg") = oSkype.CurrentUserProfile.MoodText
     OldMsg = oSkype.CurrentUserProfile.MoodText
    End If
    If AppOriginal Then
      If MediaMonkeyMoodFirst Then
        oSkype.CurrentUserProfile.MoodText = MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")" &Chr(13) &Chr(10) &ini.StringValue("SkypeMood","OldMsg")
      Else
        oSkype.CurrentUserProfile.MoodText = ini.StringValue("SkypeMood","OldMsg") &Chr(13) &Chr(10) &MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")"
      End If
    Else
      oSkype.CurrentUserProfile.MoodText = MoodPrefix &SDB.Player.CurrentSong.ArtistName &" - " &SDB.Player.CurrentSong.Title &" (" &SDB.Player.CurrentSong.SongLengthString &")"
    End If
  End If
End Sub

Sub RevertSkypeMood
  ' The Sub doesn't crash anymore, but for 'production'
  ' code, but you know, user experience has to stay pleasant
  ' even if the code bombs.
  On Error Resume Next
  '// Start the Skype client if not Running
  Dim ini, list, list2
  Dim sOldMsg
  Set ini = SDB.IniFile

  Set list = getobject("winmgmts:")
  Set list2 = list.ExecQuery("Select * from Win32_Process where name like 'Skype%'")
  If list2.count > 0 Then
    '// Create a Skype4COM object:
    Set oSkype = CreateObject("Skype4COM.Skype")
   If Not( ini Is Nothing ) Then
      sOldMsg = ini.StringValue("SkypeMood","OldMsg")
      If  sOldMsg = "" Then
         sOldMsg = OldMsg
      End If
   Else

   End If
   If Not( oSkype Is Nothing) Then
      '//revert saved Skype Mood
      oSkype.CurrentUserProfile.MoodText = sOldMsg
      '// Clear Saved mood
   End if
  End If
End Sub

[Cran]

Thanks for the credit !
But to be honest, I just fixed very few lines in your
script ...

While reading the changes, I noticed that the message is still in french !
I suggest to change line :

Code: Select all

MoodPrefix = "L'humeur du moment : "

to

Code: Select all

MoodPrefix = "Now playing: "

I added a screenshot of the skype mood area updated
by the script with the current MediaMonkey track :

[Guest]

excellent

[pelle3]

Thanks for the script! Is there a way to let it show the album title and the information in the "Year" tag?

Cheers,
pelle3

Edit:

Got it.

&SDB.Player.CurrentSong.AlbumName &" (" &SDB.Player.CurrentSong.Year &" )"

[Peke]

Easy isn't it ? Welcome to world of Scripts.

[pelle3]

:D Easy isn't it ? Welcome to world of Scripts.

Thanks

[floorman]

Whatever I edit in the script my Skype mood window alway shows this:
"np: Artist - Track name"

Any ideas why?

[Peke]

Copy/paste script here so that we can look at it?