http://www.mediamonkey.com/forum/viewtopic.php?t=11035
It however had a function to also scan for multiple album art images and create a play list, this slowed down the processing. I didn't need that so I revised the original script for single purpose and added a couple of tweaks as well.
Changes from MoDemntia's original code:
' -Removed function to create playlist of tracks with multiple covers (speeds up processing)
' -Added function to use tracks selected instead of processing all visible tracks
' -Added information box if no tracks were selected
' -Added information box at completion of processing with # tracks processed and # tracks with covers updated
Here's my script based on MoDementia's original code referenced above. First time coding with MM script so if there's improvements to be made feel free to suggest
Thanks to MoDementia for his approval to post this revised script.To install simply copy the script below and save into the Scripts/Auto folder.
To use - simply select the list of tracks you want to update and then select this script from the MM scripts list.
There are probably other scripts that have this feature bundled in, but sometimes you just want a single purpose tool and not an entire swiss army knife of gadgets. This worked for me and saved a ton of time - hopefully will have some benefit to at least another person or two. Enjoy!
Code: Select all
'==============================================================================
' MediaMonkey Script
'
' NAME: SetCovertoFront.vbs
' DESCRIPTION: Sets Cover Type to Front Cover
'
' AUTHOR: Bob61 (Based on original script FixCoverUnknown.vbs by MoDementia)
' DATE : 04/04/08
' Version: 1.0 Original release
'
' INSTALL:
' - Copy script to MediaMonkey's "Scripts\Auto" folder
'
' The script needs MediaMonkey version 2.5.3 or above - works with MediaMonkey 3.0+
'
' Select list of songs to be processed. This script will then set all image types for selection to Front Cover.
'
' Proper credit to MoDemntia for his original script FixCoverUnknown.vbs
' I was looking for script to set covers types to Front Cover and found similar script from MoDemntia
' which I adopted for single purpose which is much faster processing for large selection of files.
'
' Changes from Original Script by MoDementia:
' -Removed function to create playlist of tracks with multiple covers (speeds up processing)
' -Added function to use tracks selected instead of processing all visible tracks
' -Added information box if no tracks were selected
' -Added information box at completion of processing with # tracks processed and # tracks with covers updated
'
'
' You can see original script in this forum:
'>> ForumURL: http://www.mediamonkey.com/forum/viewtopic.php?t=11035
'==============================================================================
Option Explicit ' report undefined variables, ...
' SDB variable is connected to MediaMonkey application object
Sub OnStartup
Dim MenuItem : Set MenuItem = SDB.UI.AddMenuItem(SDB.UI.Menu_Scripts, 0, -1)
MenuItem.Caption = "Set Album Art Image Type to Front Cover"
MenuItem.Hint = "Changes Album Art Image Type to Front Cover for Selected Tracks"
MenuItem.IconIndex = 12
MenuItem.UseScript = Script.ScriptPath
MenuItem.OnClickFunc = "SetCoverToFront"
End Sub
Sub SetCoverToFront(MenuItem)
Dim objThisSongList, iCounter, Song, Album, AlbumArtList, xCounter, fCounter
Dim CoverType, NeedsUpdate
Set objThisSongList = SDB.CurrentSongList
Dim Progress, ExpText
Set Progress = SDB.Progress
ExpText = SDB.Localize("Checking Album Cover Type... ")
Progress.Text = ExpText
Progress.MaxValue = objThisSongList.Count
If objThisSongList.Count = 0 Then
SDB.MessageBox "No songs selected!", mtError, Array(mbOK)
Exit Sub
End If
fCounter = 0
For iCounter = 0 to objThisSongList.Count - 1
Progress.Text = ExpText & iCounter & " of " & objThisSongList.Count
Set Song = objThisSongList.Item(iCounter)
Set AlbumArtList = Song.AlbumArt
NeedsUpdate = 0
For xCounter = 0 to AlbumArtList.Count-1
CoverType = AlbumArtList.Item(xCounter).ItemType
If CoverType <>3 Then
NeedsUpdate = 1
AlbumArtList.Item(xCounter).ItemType = 3
fCounter = fCounter+1
End If
next
If NeedsUpdate = 1 Then
AlbumArtList.UpdateDB
End If
Progress.Value = iCounter+1
Next
SDB.MessageBox "Finished -"&iCounter& " Tracls Processed - "&fCounter&" Covers Updated", mtInformation, Array(mbOK)
End Sub 